Программа для работы со звуком :: Assembler


.model tiny
locals

.code
.startup
;ввод частоты и длительности звука
input_params:
    lea dx,msg1
    call read_int
    jc exit
    mov freq,ax
    lea dx,msg2
    call read_int
    jc exit
    mov len,ax

    lea dx,msg3
    mov ah,9
    int 21h

;расчёт коэффициента деления: c = 1193180 Гц / f
    mov ax,34DCh  ;dx:ax = 1193180
    mov dx,12h
    div freq

;запись коэффициента деления в 3-й канал таймера
    mov dx,ax
    mov al,0B6h
    out 43h,al
    mov al,dl
    out 42h,al
    mov al,dh
    out 42h,al

;включить динамик
    in al,61h
    or al,3
    out 61h,al

;задержка
    xor ax,ax
    mov es,ax
    mov ax,es:[46Ch]
    add ax,len
delay:
    mov dx,es:[46Ch]
    cmp dx,ax
    ja exit_delay
    mov dl,es:[417h]
    test dl,2
    jz delay
exit_delay:

;выключить динамик
    in al,61h
    and al,2
    out 61h,al

    jmp input_params

exit:
    mov ax,4C00h
    int 21h

;--- Ввод целого числа ---
read_int  proc
n    = word ptr [bp-2]
    push bp
    mov bp,sp
    sub sp,2
    mov n,0
    mov ah,9  ;вывод промпта
    int 21h
@@read_char:  
    mov ah,8  ;ввыод символа
    int 21h
    cmp al,27  ;ESC -> выход с CF = 1
    je @@cancel
    cmp al,13  ;CR -> завершение ввода
    je @@done
    cmp al,'0'  ;является ли введённый символ цифрой?
    jb @@read_char
    cmp al,'9'
    ja @@read_char
    push ax    ;эхопечать
    mov dx,ax
    mov ah,2
    int 21h
    pop bx
    sub bl,'0'  ;добавление цифры в результат
    xor bh,bh
    mov ax,10
    mul n
    add ax,bx
    mov n,ax
    jmp @@read_char
;выход с CF = 1
@@cancel:
    stc
    jmp @@exit
@@done:
;переход на новую строку
    mov dl,13
    mov ah,2
    int 21h
    mov dl,10
    mov ah,2
    int 21h
;выход с результатом в AX и CF = 0
    mov ax,n
    clc
@@exit:
    mov sp,bp
    pop bp
    ret
read_int  endp

.data?
freq    dw ?
len    dw ?

.const
msg1    db 'Частота [Гц]> $'
msg2    db 'Длительность [1/18 с]> $'
msg3    db 13,10,'Левый <Shift> - прервать сигнал',13,10,13,10,'$'

end

Объединенный Открытый Проект

Сайт для Настоящих Компьютерщиков

Объединенный Открытый Проект » Программирование » Assembler » Программа для работы со звуком

Программа для работы со звуком

Объединенный Открытый Проект » Программирование » Assembler » Программа для работы со звуком